朋友们好!上一讲我们试着编写了一个自用成交量公式,主要把倍量公式给高亮显示并且在倍量柱的上方写上一个“倍”字。并留了作业,就是把其他几种量也在量柱上方写上相应的字,如果喜欢高亮显示,也可以用同样的方法给显示出来。
但文章发布后,还是有粉丝朋友来问,怎么把地量也给高亮显示。
那今天先来解决上一讲的遗留问题:
(1)补全“我的成交量”公式:
…… …… …… …… ……
成交量:V,VOLSTICK;
地量:V<=REF(LLV(V,100),1);
倍量:V>=REF(V,1)*1.99 AND C>=REF(C,1),COLORYELLOW;
平量:V/REF(V,1)<1.03 AND V/REF(V,1)>0.97;
半量: V<=REF(V,1)*0.49;
梯量: EVERY (V>REF(V,1),3);
缩量: EVERY (V<REF(V,1),3);
MA5:MA(V,5);
MA40:MA(V,40;
DRAWTEXT(倍量,V+20000,'倍'),COLORYELLOW;
STICKLINE(倍量,0,V,2,0), COLORYELLOW;
…… …… …… …… ……
其实只要把这两句改写就行了:
DRAWTEXT(倍量,V,'倍'),COLORYELLOW;
{当出现倍量时,就在倍量所在位置的成交量“V”上方显示黄色“倍”}
STICKLINE(倍量,0,V,2,0), COLORYELLOW;
{当出现倍量时,就将倍量柱用黄色的柱状线显示,颜色为黄色}
那如果我们要想把地量(这里指的是百日地量)高亮洋红色显示,“地”字也用洋红色显示,则可以把上面两句修改为:
DRAWTEXT(地量,V,'地'), COLORMAGENTA;
DRAWTEXT(地量,V,'地'), COLORMAGENTA;
同理,修改其他量的文字显示,高亮显示有了两个就差不多了,太多会感觉眼花缭乱的。
“我的成交量”源码
…… …… …… …… ……
成交量:V,VOLSTICK;
地量:V<=REF(LLV(V,100),1);
倍量:V>=REF(V,1)*1.99 AND C>=REF(C,1),COLORYELLOW;
平量:V/REF(V,1)<1.03 AND V/REF(V,1)>0.97;
半量: V<=REF(V,1)*0.49;
梯量: EVERY (V>REF(V,1),3);
缩量: EVERY (V<REF(V,1),3);
MA5:MA(V,5),COLORYELLOW;
MA40:MA(V,40),COLORGREEN;
DRAWTEXT(倍量,V+20000,'倍'),COLORYELLOW;
STICKLINE(倍量,0,V,2,0),COLORYELLOW;
DRAWTEXT(地量,V+20000,'地'),COLOR0080FF;
STICKLINE(地量,0,V,2,0),COLOR0080FF;
DRAWTEXT(平量,V+20000,'平'),COLORC67760;
DRAWTEXT(半量,V+20000,'半'),COLORC67760;
DRAWTEXT(梯量,V+20000,'梯'),COLORC67760;
DRAWTEXT(缩量,V+20000,'缩'),COLORC67760;
…… …… …… …… ……
大家可能都看到在“V”的后面都加了20000这个数字吧,这是因为文章发布后,发现在成交量柱上方显示的“倍”字离成交量柱太近了,我试着调整了,在V后面+20000比较合适。
(2)关于“系统选股”和“用户选股的问题”:
昨天文章发布后,有粉丝来要条件选股公式,其实倍量、百日地量选股公式很简单的,就一句话:
倍量选股:倍量:V>=REF(V,1)*1.99 AND C>=REF(C,1);
百日地量选股:地量:V<=REF(LLV(V,100),1);
其实昨天还教了大家另外一种选股方法,只需要将指标公式里的条件在“综合选股”中进行选股就可以了。
那今天再详细说一下:
【功能】→【选股器】→【综合选股】,点击出现综合选股窗口:
如果是用系统指标进行选股,就点击上方的“系统条件”;如果是用自编指标进行选股,就点击“用户条件”,比如我们要用倍量来选股,1、点击“我的成交量”,我将它放在“成交量型”的下方;
2、在左中下方,“倍量”“等于”“1”,都有相应的下拉菜单可以选择;
3;在右上方框中点击“加入条件”;
4、在右下方,有三个小方框,分别打勾;
5、选股范围:可以是沪深两市所有的股票,也可以换成你自己喜欢的板块,点击“改变范围”修改即可;
6、执行选股。刚才试了一下,选出了87只倍量的股票。
(3)MACD的变色公式
下面我们来学习MACD指标的有关编写问题。
MACD,中文名称:平滑异同平均线。是系统自带的、比较经典的指标之一。
但有时我们会看到别人的MACD指标比系统自带的MACD指标的图形看起来更舒适。如下图所示:
图中上方的副图是系统自带的MACD指标,下图是改良过的MACD变色指标。拾荒网股票学习网专注短线龙头战法~今天我们来看看这个MACD变色指标是怎么编写的?
直接上源码:
…… …… …… …… ……
DIFIF1:=EMA(CLOSE,12) - EMA(CLOSE,26);
DEAEA1:=EMA(DIFIF1,9);
MACD1:=2*(DIFIF1-DEAEA1),STICK;
MACD2:=EMA(MACD1,2);
STICKLINE(MACD1>MACD2 AND MACD1>0,0,MACD1,1,0),COLORRED;
STICKLINE(MACD1>MACD2 AND MACD1<0,0,MACD1,1,0),COLORGREEN;
STICKLINE(MACD1<MACD2,0,MACD1,1,0),COLORCBCBC0;
STICKLINE(MACD1>=0 OR MACD1<=0,0,0,50,1),COLORWHITE;
DIFIF1,COLOR33FF33,LINETHICK2;
DEAEA1,COLORYELLOW,LINETHICK2;
MACD:MACD1,NODRAW,COLORMAGENTA;
强:IF(DIFIF1>=DEAEA1,DIFIF1,DRAWNULL),COLORRED,LINETHICK2;
弱:IF(DEAEA1>=DIFIF1,DEAEA1,DRAWNULL),COLORFF9900,LINETHICK2;
DRAWICON(CROSS(DIFIF1,DEAEA1),DIFIF1-0.05,1);
…… …… …… …… ……
公式分为三组:
(1)将系统MACD指标的源码复制过来:
DIFIF1:=EMA(CLOSE,12) - EMA(CLOSE,26);
DEAEA1:=EMA(DIFIF1,9);
MACD1:=2*(DIFIF1-DEAEA1),STICK;
MACD2:=EMA(MACD1,2);
这是将系统MACD指标的源码复制过来进行赋值(冒号后面加个“=“),把参数全部换成具体数字。因为要进行大小比较换颜色,所以增加了一条MACD2。
(2)下面一组是画柱状线:
STICKLINE(MACD1>MACD2 AND MACD1>0,0,MACD1,1,0),COLORRED;
{当满足条件MACD1>MACD2 和 MACD1>0时,在0到MACD1之间画柱状线,红色,宽度为1}
STICKLINE(MACD1>MACD2 AND MACD1<0,0,MACD1,1,0),COLORGREEN;
{当满足条件MACD1>MACD2 和 MACD1<0时,在0到MACD1之间画柱状线,绿色,宽度为1}
STICKLINE(MACD1<MACD2,0,MACD1,1,0),COLORCBCBC0;
{当满足条件MACD1<MACD2时,在0到MACD1之间画柱状线,颜色为COLORCBCBC0(后面会说,在插入资源里),宽度为1}
STICKLINE(MACD1>=0 OR MACD1<=0,0,0,50,1),COLORWHITE;
{当满足条件MACD1>=0 或者MACD1<=0时,在0到0之间画柱状线,白色,宽度为50,即画0轴}
(3)这一组是对快、慢线进行处理:
DIFIF1,COLOR33FF33,LINETHICK2;
{快线,颜色COLOR33FF33,线宽2}
DEAEA1,COLORYELLOW,LINETHICK2;{慢线,黄色,线宽2}
MACD:MACD1,NODRAW,COLORMAGENTA;
{输出MACD,如果等于MACD1则画洋红色,否则不画线}
强:IF(DIFIF1>=DEAEA1,DIFIF1,DRAWNULL),COLORRED,LINETHICK2;
{如果DIFIF1>=DEAEA1则返回DIFIF1,画红色线宽2,否则返回无效数}
弱:IF(DEAEA1>=DIFIF1,DEAEA1,DRAWNULL),COLORFF9900,LINETHICK2;
{如果DEAEA1>=DIFIF1则返回DEAEA1,画COLORFF9900色,线宽2,否则返回无效数}
DRAWICON(CROSS(DIFIF1,DEAEA1),DIFIF1-0.05,1);
{当满足条件DIFIF1金叉DEAEA1时,在金叉下方0.05处画1号图标,即向上剪头}
源码可以复制、粘贴,但我希望朋友们能看懂公式的意思。通过这些日子的学习,对照常用的函数,一般的公式基本都能看懂的。
小结:
1、将上一次留的作业和大家一起补全,并再次介绍系统选股的方法;
2、学习了MACD变色指标的编写方法。
对于MACD指标,市场上用的人很多,方法也很多,但我比较看重MACD的两种买点(底背离买点、零上金叉买点)和一种卖点(顶背离卖点)。这些下一讲将和朋友们分享。
标签: 通达信指标编写